ts_calc.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	ts_calc (xflow, Tt, Pt, kappa, r, A, Ts, icase)

Function/Subroutine Documentation

ts_calc()

subroutine ts_calc	(	real*8, intent(in)	xflow,
		real*8, intent(in)	Tt,
		real*8, intent(in)	Pt,
		real*8, intent(in)	kappa,
		real*8, intent(in)	r,
		real*8, intent(in)	A,
		real*8, intent(inout)	Ts,
		integer, intent(in)	icase
	)

!     
!     Calculation of the static temperature Ts from the total 
!     temperature Tt, the total pressure Pt and the mass flow xflow
!
!     this subroutine solves the implicit equation
!     xflow*dsqrt(Tt)/(A*Pt)-C*(Tt/Ts)**expon*(Tt/Ts-1)**0.5d0=0.d0
!
!          expon=-0.5d0*(kappa+1.d0)/(kappa-1.d0)
!          C=dsqrt(2.d0/r*kappa/(kappa-1.d0))
!
!     xflow is the mass flow for 360 degrees, sign is irrelevant
!     for this routine
!
!     author: Yannick Muller
!     
      implicit none
!
      integer icase,i
!     
      real*8 xflow,tt,pt,ts,kappa,r,f,df,a,expon,ts_old,c,ttzts,
     &     deltats,ttzts_crit, qred_crit,qred,h1,h2,h3
!
      intent(in) xflow,tt,pt,kappa,r,a,icase
!
      intent(inout) ts
!
      expon=-0.5d0*(kappa+1.d0)/(kappa-1.d0)
!     
      c=dsqrt(2.d0/r*kappa/(kappa-1.d0))
!     
!     f=xflow*dsqrt(Tt)/(A*Pt)-C*(Tt/Ts)**expon*(Tt/Ts-1)**0.5d0
!
!     df=-C*Tt/Ts**expon*(expon/Ts*(Tt/Ts-1)**0.5d0
!     &     -0.5d0*Tt/Ts/Ts*(Tt/Ts-1.d0)**(-0.5d0))
!     
      ts_old=tt
!    
      if(dabs(xflow).le.1e-9) then
         ts=tt
         return
      endif
!
      qred=abs(xflow)*dsqrt(tt)/(a*pt)
!
!     optimised estimate of T static
!
      ts=tt/(1+(qred**2/c**2))
!     
!     adiabatic
!     
      if(icase.eq.0) then
         ttzts_crit=(kappa+1.d0)/2.d0
!         
!     isothermal
!
      else
         ttzts_crit=(1d0+(kappa-1.d0)/(2.d0*kappa))
      endif
!
      qred_crit=c*(ttzts_crit)**expon*(ttzts_crit-1.d0)**0.5d0
!     
      if(qred.ge.qred_crit) then
         ts=tt/ttzts_crit
         return
      endif
!
      i=0
!     
!     start of the Newton-Raphson-Procedure to solve the nonlinear
!     equation
!
      do 
         i=i+1
         ttzts=tt/ts
         h1=ttzts-1.d0
         h2=dsqrt(h1)
         h3=ttzts**expon
!     
         f=c*h2*h3
!     
         df=f*(expon+0.5d0*ttzts/h1)/ts
!
         f=qred-f
         deltats=-f/df
!     
         ts=ts+deltats
!     
         if((((dabs(ts-ts_old)/ts_old).le.1.e-8))
     &        .or.((dabs(ts-ts_old)).le.1.e-10)) then
            exit
         else if(i.gt.20) then
            ts=0.9*tt
            exit
         endif
         ts_old=ts
      enddo
!     
      return