transformfs.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	transformfs (inpc, textpart, trab, ntrans, ntrans_, set, istartset, iendset, ialset, nset, istep, istat, n, iline, ipol, inl, ipoinp, inp, ipoinpc, xload, sideload, nelemload, idefload, nload, nload_, ne, nam, iamload)

Function/Subroutine Documentation

transformfs()

subroutine transformfs	(	character*1, dimension(*)	inpc,
		character*132, dimension(16)	textpart,
		real*8, dimension(7,*)	trab,
		integer	ntrans,
		integer	ntrans_,
		character*81, dimension(*)	set,
		integer, dimension(*)	istartset,
		integer, dimension(*)	iendset,
		integer, dimension(*)	ialset,
		integer	nset,
		integer	istep,
		integer	istat,
		integer	n,
		integer	iline,
		integer	ipol,
		integer	inl,
		integer, dimension(2,*)	ipoinp,
		integer, dimension(3,*)	inp,
		integer, dimension(0:*)	ipoinpc,
		real*8, dimension(2,*)	xload,
		character*20, dimension(*)	sideload,
		integer, dimension(2,*)	nelemload,
		integer, dimension(*)	idefload,
		integer	nload,
		integer	nload_,
		integer	ne,
		integer	nam,
		integer, dimension(*)	iamload
	)

!
!     reading the input deck: *TRANSFORMF
!
      implicit none
!
      real*8 trab(7,*)
!
      character*1 inpc(*)
      character*20 sideload(*),label
      character*81 set(*),surfaceset
      character*132 textpart(16)
!
      integer ntrans,ntrans_,istep,istat,n,key,i,j,
     &  istartset(*),iendset(*),ialset(*),nset,ipos,iline,ipol,
     &  inl,ipoinp(2,*),inp(3,*),ipoinpc(0:*),nelemload(2,*),ne,
     &  nam,nload,l,iamload(*),iamplitude,idefload(*),
     &  nload_,iset,nelem,ifacel
!
      real*8 xload(2,*),xmagnitude
!
      if(istep.gt.0) then
         write(*,*) '*ERROR reading *TRANSFORMF: *TRANSFORMF should be'
         write(*,*) '  placed before all step definitions'
         call exit(201)
      endif
!
      ntrans=ntrans+1
      if(ntrans.gt.ntrans_) then
         write(*,*) '*ERROR reading *TRANSFORMF: increase ntrans_'
         call exit(201)
      endif
!
      ipos=1
      xmagnitude=0.d0
      iamplitude=0
!
!     rectangular coordinate system: trab(7,norien)=1
!     cylindrical coordinate system: trab(7,norien)=-1
!     default is rectangular
!
      trab(7,ntrans)=1.d0
!
      do i=2,n
         if(textpart(i)(1:5).eq.'TYPE=') then
            if(textpart(i)(6:6).eq.'C') then
               trab(7,ntrans)=-1.d0
            endif
         elseif(textpart(i)(1:8).eq.'SURFACE=') then
            surfaceset(1:80)=textpart(i)(9:88)
            surfaceset(81:81)=' '
            ipos=index(surfaceset,' ')
            surfaceset(ipos:ipos)='T'
            do iset=1,nset
               if(set(iset).eq.surfaceset) exit
            enddo
            if(iset.gt.nset) then
               write(*,*) 
     &             '*WARNING reading *TRANSFORMF: element surface ',
     &              surfaceset(1:ipos-1),' does not exist'
               call getnewline(inpc,textpart,istat,n,key,iline,ipol,inl,
     &              ipoinp,inp,ipoinpc)
               return
            endif
         else
            write(*,*) 
     &        '*WARNING reading *TRANSFORMF: parameter not recognized:'
            write(*,*) '         ',
     &                 textpart(i)(1:index(textpart(i),' ')-1)
            call inputwarning(inpc,ipoinpc,iline,
     &"*TRANSFORMF%")
         endif
      enddo
!
      call getnewline(inpc,textpart,istat,n,key,iline,ipol,inl,
     &     ipoinp,inp,ipoinpc)
      if((istat.lt.0).or.(key.eq.1)) then
         write(*,*)'*ERROR reading *TRANSFORMF: definition of a'
         write(*,*) '  transformation is not complete'
         call inputerror(inpc,ipoinpc,iline,
     &"*TRANSFORMF%")
         call exit(201)
      endif
!
      do i=1,6
         read(textpart(i)(1:20),'(f20.0)',iostat=istat) trab(i,ntrans)
         if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*TRANSFORMF%")
      enddo
!
      label(1:20)='T                   '
      do j=istartset(iset),iendset(iset)
         l=ialset(j)
         nelem=int(l/10.d0)
         ifacel=l-10*nelem
         write(label(2:2),'(i1)') ifacel
         call loadadd(nelem,label,xmagnitude,nelemload,
     &        sideload,xload,nload,nload_,iamload,
     &        iamplitude,nam,ntrans,idefload)
      enddo
!     
      call getnewline(inpc,textpart,istat,n,key,iline,ipol,inl,
     &     ipoinp,inp,ipoinpc)
!
      return