shape4tet.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	shape4tet (xi, et, ze, xl, xsj, shp, iflag)

Function/Subroutine Documentation

shape4tet()

subroutine shape4tet	(	real*8, intent(in)	xi,
		real*8, intent(in)	et,
		real*8, intent(in)	ze,
		real*8, dimension(3,4), intent(in)	xl,
		real*8, intent(out)	xsj,
		real*8, dimension(4,4), intent(out)	shp,
		integer, intent(in)	iflag
	)

!
!     shape functions and derivatives for a 4-node linear
!     isoparametric tetrahedral element. 0<=xi,et,ze<=1,xi+et+ze<=1.
!
!     iflag=1: calculate only the value of the shape functions
!     iflag=2: calculate the value of the shape functions and
!              the Jacobian determinant
!     iflag=3: calculate the value of the shape functions, the
!              value of their derivatives w.r.t. the global
!              coordinates and the Jacobian determinant
!
      implicit none
!
      integer i,j,k,iflag
!
      real*8 shp(4,4),xs(3,3),xsi(3,3),xl(3,4),sh(3)
!
      real*8 xi,et,ze,xsj
!
      intent(in) xi,et,ze,xl,iflag
!
      intent(out) shp,xsj
!
!     shape functions and their glocal derivatives
!
!     shape functions
!
      shp(4, 1)=1.d0-xi-et-ze
      shp(4, 2)=xi
      shp(4, 3)=et
      shp(4, 4)=ze
!
      if(iflag.eq.1) return
!
!     local derivatives of the shape functions: xi-derivative
!
      shp(1, 1)=-1.d0
      shp(1, 2)=1.d0
      shp(1, 3)=0.d0
      shp(1, 4)=0.d0
!
!     local derivatives of the shape functions: eta-derivative
!
      shp(2, 1)=-1.d0
      shp(2, 2)=0.d0
      shp(2, 3)=1.d0
      shp(2, 4)=0.d0
!
!     local derivatives of the shape functions: zeta-derivative
!
      shp(3, 1)=-1.d0
      shp(3, 2)=0.d0
      shp(3, 3)=0.d0
      shp(3, 4)=1.d0
!
!     computation of the local derivative of the global coordinates
!     (xs)
!
      do i=1,3
        do j=1,3
          xs(i,j)=0.d0
          do k=1,4
            xs(i,j)=xs(i,j)+xl(i,k)*shp(j,k)
          enddo
        enddo
      enddo
!
!     computation of the jacobian determinant
!
      xsj=xs(1,1)*(xs(2,2)*xs(3,3)-xs(2,3)*xs(3,2))
     &   -xs(1,2)*(xs(2,1)*xs(3,3)-xs(2,3)*xs(3,1))
     &   +xs(1,3)*(xs(2,1)*xs(3,2)-xs(2,2)*xs(3,1))
!
      if(iflag.eq.2) return
!
!     computation of the global derivative of the local coordinates
!     (xsi) (inversion of xs)
!
      xsi(1,1)=(xs(2,2)*xs(3,3)-xs(3,2)*xs(2,3))/xsj
      xsi(1,2)=(xs(1,3)*xs(3,2)-xs(1,2)*xs(3,3))/xsj
      xsi(1,3)=(xs(1,2)*xs(2,3)-xs(2,2)*xs(1,3))/xsj
      xsi(2,1)=(xs(2,3)*xs(3,1)-xs(2,1)*xs(3,3))/xsj
      xsi(2,2)=(xs(1,1)*xs(3,3)-xs(3,1)*xs(1,3))/xsj
      xsi(2,3)=(xs(1,3)*xs(2,1)-xs(1,1)*xs(2,3))/xsj
      xsi(3,1)=(xs(2,1)*xs(3,2)-xs(3,1)*xs(2,2))/xsj
      xsi(3,2)=(xs(1,2)*xs(3,1)-xs(1,1)*xs(3,2))/xsj
      xsi(3,3)=(xs(1,1)*xs(2,2)-xs(2,1)*xs(1,2))/xsj
!
!     computation of the global derivatives of the shape functions
!
      do k=1,4
        do j=1,3
          sh(j)=shp(1,k)*xsi(1,j)+shp(2,k)*xsi(2,j)+shp(3,k)*xsi(3,j)
        enddo
        do j=1,3
          shp(j,k)=sh(j)
        enddo
      enddo
!
      return