materialdata_cfd.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	materialdata_cfd (nef, vel, shcon, nshcon, ielmatf, ntmat_, mi, cvel, vfa, cocon, ncocon, physcon, cvfa, ithermal, nface, umel, umfa, ielfa, hcfa, rhcon, nrhcon)

Function/Subroutine Documentation

materialdata_cfd()

subroutine materialdata_cfd	(	integer, intent(in)	nef,
		real*8, dimension(nef,0:7), intent(inout)	vel,
		real*8, dimension(0:3,ntmat_,*), intent(in)	shcon,
		integer, dimension(2,*), intent(in)	nshcon,
		integer, dimension(mi(3),*), intent(in)	ielmatf,
		integer, intent(in)	ntmat_,
		integer, dimension(*), intent(in)	mi,
		real*8, dimension(*), intent(inout)	cvel,
		real*8, dimension(0:7,*), intent(inout)	vfa,
		real*8, dimension(0:6,ntmat_,*), intent(in)	cocon,
		integer, dimension(2,*), intent(in)	ncocon,
		real*8, dimension(*), intent(in)	physcon,
		real*8, dimension(*), intent(inout)	cvfa,
		integer, intent(in)	ithermal,
		integer, intent(in)	nface,
		real*8, dimension(*), intent(inout)	umel,
		real*8, dimension(*), intent(inout)	umfa,
		integer, dimension(4,*), intent(in)	ielfa,
		real*8, dimension(*), intent(inout)	hcfa,
		real*8, dimension(0:1,ntmat_,*)	rhcon,
		integer, dimension(*)	nrhcon
	)

!
!     calculation of material properties at elements centers and
!     face centers (incompressible fluids)
!
      implicit none
!
      integer nef,i,imat,ntmat_,mi(*),ielmatf(mi(3),*),ithermal,
     &  nshcon(2,*),nface,ncocon(2,*),ielfa(4,*),nrhcon(*)
!
      real*8 t1l,vel(nef,0:7),shcon(0:3,ntmat_,*),cvel(*),vfa(0:7,*),
     &  cocon(0:6,ntmat_,*),physcon(*),cvfa(*),umel(*),umfa(*),
     &  hcfa(*),rhcon(0:1,ntmat_,*)
!
      intent(in) nef,shcon,nshcon,ielmatf,
     &  ntmat_,mi,cocon,ncocon,physcon,ithermal,nface,
     &  ielfa
!
      intent(inout) vel,vfa,cvel,cvfa,umel,umfa,hcfa
!     
c$omp parallel default(none)
c$omp& shared(nef,vel,ielmatf,shcon,ntmat_,nshcon,physcon,cvel,umel,
c$omp&        ithermal,nface,vfa,ielfa,cvfa,umfa,hcfa,cocon,ncocon,
c$omp&        rhcon,nrhcon)
c$omp& private(i,t1l,imat)
!
!     element (cell) values
!
c$omp do
      do i=1,nef
         t1l=vel(i,0)
         imat=ielmatf(1,i)
!
!        density
!
         call materialdata_rho(rhcon,nrhcon,imat,vel(i,5),t1l,ntmat_,
     &            ithermal)
!
!        heat capacity at constant volume
!        (for liquids: =heat capacity at constant pressure)
!
         call materialdata_cp_sec(imat,ntmat_,t1l,shcon,nshcon,cvel(i),
     &       physcon)
!
!        dynamic viscosity
!
         call materialdata_dvi(shcon,nshcon,imat,umel(i),t1l,ntmat_,
     &            ithermal)
      enddo
c$omp end do
!
!     facial values
!
c$omp do
      do i=1,nface
         t1l=vfa(0,i)
!
!        take the material of the first adjacent element
!
         imat=ielmatf(1,ielfa(1,i))
!
!        density
!
         call materialdata_rho(rhcon,nrhcon,imat,vfa(5,i),t1l,ntmat_,
     &            ithermal)
!
!        heat capacity at constant volume
!
         call materialdata_cp_sec(imat,ntmat_,t1l,shcon,nshcon,cvfa(i),
     &       physcon)
!
!        dynamic viscosity
!
         call materialdata_dvi(shcon,nshcon,imat,umfa(i),t1l,ntmat_,
     &            ithermal)
!
!        heat conduction
!
         call materialdata_cond(imat,ntmat_,t1l,cocon,ncocon,hcfa(i))
      enddo
c$omp end do
c$omp end parallel
!            
      return