hns.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	hns (b, theta, rho, dg, sqrts0, xflow, h1, h2)

Function/Subroutine Documentation

hns()

subroutine hns	(	real*8	b,
		real*8	theta,
		real*8	rho,
		real*8	dg,
		real*8	sqrts0,
		real*8	xflow,
		real*8	h1,
		real*8	h2
	)

!
!     determine the flow depth h2 downstream of a hydraulic jump, 
!     corresponding to a upstream flow depth of h1
!     
      implicit none
!      
      real*8 b,rho,dg,sqrts0,xflow,h1,h2,c2,f,df,dh2,hk,
     &  xflow2,tth,a1,yg1,a2,yg2,da2dh2,dyg2dh2,theta
!
      call hcrit(xflow,rho,b,theta,dg,sqrts0,hk)
!
      h2=h1*(-1.d0+dsqrt(1.d0+8.d0*(hk/h1)**3))/2.d0
!
      if(dabs(theta).lt.1.d-10) return
!
!     hns for a trapezoid, non-rectangular cross section
!
      c2=rho*rho*dg*sqrts0
      xflow2=xflow*xflow
      tth=dtan(theta)
      a1=h1*(b+h1*tth)
      yg1=h1*(3.d0*b+2.d0*h1*tth)/(6.d0*(b+h1*tth))
!
!     Newton-Raphson iterations
!
      do
         a2=h2*(b+h2*tth)
         yg2=h2*(3.d0*b+2.d0*h2*tth)/(6.d0*(b+h2*tth))
         da2dh2=b+2.d0*h2*tth
         dyg2dh2=((3.d0*b+4.d0*h2*tth)*(b+tth)
     &                    -tth*h2*(3.d0*b+2.d0*h2*tth))/
     &                    (6.d0*(b+h2*tth)**2)
         f=a2*xflow2+c2*(a1*a1*a2*yg1-a1*a2*a2*yg2)-a1*xflow2
         df=da2dh2*xflow2+c2*(a1*a1*yg1*da2dh2-2.d0*a1*a2*da2dh2*yg2
     &                       -a1*a2*a2*dyg2dh2)
         dh2=f/df
         if(dabs(dh2)/h2.lt.1.d-3) exit
         h2=h2-dh2
      enddo
!
      write(*,*) 'hns ','h1= ',h1,'h2= ',h2,'hk= ',hk
!
      return