cfds.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	cfds (inpc, textpart, nmethod, iperturb, isolver, istep, istat, n, tinc, tper, tmin, tmax, idrct, ithermal, iline, ipol, inl, ipoinp, inp, ipoinpc, alpha, ctrl, iexpl, tincf, ttime, physcon)

Function/Subroutine Documentation

cfds()

subroutine cfds	(	character*1, dimension(*)	inpc,
		character*132, dimension(16)	textpart,
		integer	nmethod,
		integer	iperturb,
		integer	isolver,
		integer	istep,
		integer	istat,
		integer	n,
		real*8	tinc,
		real*8	tper,
		real*8	tmin,
		real*8	tmax,
		integer	idrct,
		integer	ithermal,
		integer	iline,
		integer	ipol,
		integer	inl,
		integer, dimension(2,*)	ipoinp,
		integer, dimension(3,*)	inp,
		integer, dimension(0:*)	ipoinpc,
		real*8	alpha,
		real*8, dimension(*)	ctrl,
		integer	iexpl,
		real*8	tincf,
		real*8	ttime,
		real*8, dimension(*)	physcon
	)

!
!     reading the input deck: *CFD
!
!     isolver=0: SPOOLES
!             2: iterative solver with diagonal scaling
!             3: iterative solver with Cholesky preconditioning
!             4: sgi solver
!             5: TAUCS
!             7: pardiso
!
!      iexpl==0:  structure:implicit, fluid:incompressible
!      iexpl==1:  structure:implicit, fluid:compressible
!
      implicit none
!
      logical timereset
!
      character*1 inpc(*)
      character*20 solver
      character*132 textpart(16)
!
      integer nmethod,iperturb,isolver,istep,istat,n,key,i,idrct,
     &  ithermal,iline,ipol,inl,ipoinp(2,*),inp(3,*),ipoinpc(0:*),
     &  iexpl
!
      real*8 tinc,tper,tmin,tmax,alpha,ctrl(*),tincf,ttime,physcon(*)
!
      idrct=0
      alpha=-0.05d0
      tmin=0.d0
      tmax=0.d0
      tincf=-1.d0
      nmethod=4
      timereset=.false.
      physcon(9)=0.5d0
!
      if(iperturb.eq.0) then
         iperturb=2
      elseif((iperturb.eq.1).and.(istep.gt.1)) then
         write(*,*) '*ERROR reading *CFD: perturbation analysis is'
         write(*,*) '       not provided in a *HEAT TRANSFER step.'
         call exit(201)
      endif
!
      if(istep.lt.1) then
         write(*,*) '*ERROR reading *CFD: *HEAT TRANSFER can only '
         write(*,*) '       be used within a STEP'
         call exit(201)
      endif
!
!     default solver
!
      solver='                    '
      if(isolver.eq.0) then
         solver(1:7)='SPOOLES'
      elseif(isolver.eq.2) then
         solver(1:16)='ITERATIVESCALING'
      elseif(isolver.eq.3) then
         solver(1:17)='ITERATIVECHOLESKY'
      elseif(isolver.eq.4) then
         solver(1:3)='SGI'
      elseif(isolver.eq.5) then
         solver(1:5)='TAUCS'
      elseif(isolver.eq.7) then
         solver(1:7)='PARDISO'
      endif
!
      do i=2,n
         if(textpart(i)(1:7).eq.'SOLVER=') then
            read(textpart(i)(8:27),'(a20)') solver
         elseif(textpart(i)(1:12).eq.'COMPRESSIBLE') then
            iexpl=1
         elseif(textpart(i)(1:11).eq.'STEADYSTATE') then
            nmethod=1
         elseif(textpart(i)(1:9).eq.'TIMERESET') then
            timereset=.true.
         elseif(textpart(i)(1:17).eq.'TOTALTIMEATSTART=') then
            read(textpart(i)(18:37),'(f20.0)',iostat=istat) ttime
         elseif(textpart(i)(1:16).eq.'TURBULENCEMODEL=') then
!
!           turbulence model
!
            if(textpart(i)(17:25).eq.'NONE') then
               physcon(9)=0.5d0
            elseif(textpart(i)(17:25).eq.'K-EPSILON') then
               physcon(9)=1.5d0
            elseif(textpart(i)(17:23).eq.'K-OMEGA') then
               physcon(9)=2.5d0
            elseif(textpart(i)(17:19).eq.'SST') then
               physcon(9)=3.5d0
            endif
         else
            write(*,*) 
     &        '*WARNING reading *CFD: parameter not recognized:'
            write(*,*) '         ',
     &                 textpart(i)(1:index(textpart(i),' ')-1)
            call inputwarning(inpc,ipoinpc,iline,
     &"*CFD%")
         endif
      enddo
      if(nmethod.eq.1) ctrl(27)=1.d30
!
      if((ithermal.eq.0).and.(iexpl.eq.1)) then
         write(*,*) '*ERROR reading *CFD: please define initial '
         write(*,*) '       conditions for the temperature'
         call exit(201)
      elseif(ithermal.gt.0) then
         ithermal=3
      endif
!
      if(solver(1:7).eq.'SPOOLES') then
         isolver=0
      elseif(solver(1:16).eq.'ITERATIVESCALING') then
         isolver=2
      elseif(solver(1:17).eq.'ITERATIVECHOLESKY') then
         isolver=3
      elseif(solver(1:3).eq.'SGI') then
         isolver=4
      elseif(solver(1:5).eq.'TAUCS') then
         isolver=5
      elseif(solver(1:7).eq.'PARDISO') then
         isolver=7
      else
         write(*,*) '*WARNING reading *CFD: unknown solver;'
         write(*,*) '         the default solver is used'
      endif
!
      call getnewline(inpc,textpart,istat,n,key,iline,ipol,inl,
     &     ipoinp,inp,ipoinpc)
      if((istat.lt.0).or.(key.eq.1)) then
         if(nmethod.eq.4) then
!
!           transient cfd
!
            write(*,*) '*WARNING reading *CFD: a nonlinear geometric
     & analysis is requested'
            write(*,*) '         but no time increment nor step is speci
     &fied'
            write(*,*) '         the defaults (1,1) are used'
            tinc=1.d0
            tper=1.d0
            tmin=1.d-5
            tmax=1.d+30
            tincf=-1.d0
         elseif(nmethod.eq.1) then
!
!           steady state cfd: initial increment time and step
!           time are set to large values since only the first
!           increment is calculated
!
            tinc=1.d+30
            tper=1.d+30
            tmin=1.d-5
            tmax=1.d+30
            tincf=-1.d0
         endif
         if(timereset)ttime=ttime-tper
         return
      endif
!
      read(textpart(1)(1:20),'(f20.0)',iostat=istat) tinc
      if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*CFD%")
      read(textpart(2)(1:20),'(f20.0)',iostat=istat) tper
      if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*CFD%")
      read(textpart(3)(1:20),'(f20.0)',iostat=istat) tmin
      if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*CFD%")
      read(textpart(4)(1:20),'(f20.0)',iostat=istat) tmax
      if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*CFD%")
      read(textpart(5)(1:20),'(f20.0)',iostat=istat) tincf
      if(istat.gt.0) call inputerror(inpc,ipoinpc,iline,
     &"*CFD%")
!
      if(tinc.le.0.d0) then
         write(*,*) '*ERROR reading *CFD: initial increment size is 
     &negative'
      endif
      if(tper.le.0.d0) then
         write(*,*) '*ERROR reading *CFD: step size is negative'
      endif
      if(tinc.gt.tper) then
         write(*,*) '*ERROR reading *CFD: initial increment size exc
     &eeds step size'
      endif
!      
      if(idrct.ne.1) then
         if(dabs(tmin).lt.1.d-6*tper) then
            tmin=min(tinc,1.d-6*tper)
         endif
         if(dabs(tmax).lt.1.d-10) then
            tmax=1.d+30
         endif
         if(tinc.gt.dabs(tmax)) then
            write(*,*) '*WARNING reading *CFD:'
            write(*,*) '         the initial increment ',tinc
            write(*,*) '         exceeds the maximum increment ',
     &          tmax
            write(*,*) '         the initial increment is reduced'
            write(*,*) '         to the maximum value'
            tinc=dabs(tmax)
         endif
      endif
!
      if(timereset)ttime=ttime-tper
!
      call getnewline(inpc,textpart,istat,n,key,iline,ipol,inl,
     &     ipoinp,inp,ipoinpc)
!
      return