carbon_seal.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	carbon_seal (node1, node2, nodem, nelem, lakon, nactdog, identity, ielprop, prop, iflag, v, xflow, f, nodef, idirf, df, R, physcon, dvi, numf, set, mi, ttime, time, iaxial)

Function/Subroutine Documentation

carbon_seal()

subroutine carbon_seal	(	integer	node1,
		integer	node2,
		integer	nodem,
		integer	nelem,
		character*8, dimension(*)	lakon,
		integer, dimension(0:3,*)	nactdog,
		logical	identity,
		integer, dimension(*)	ielprop,
		real*8, dimension(*)	prop,
		integer	iflag,
		real*8, dimension(0:mi(2),*)	v,
		real*8	xflow,
		real*8	f,
		integer, dimension(*)	nodef,
		integer, dimension(*)	idirf,
		real*8, dimension(*)	df,
		real*8	R,
		real*8, dimension(*)	physcon,
		real*8	dvi,
		integer	numf,
		character*81, dimension(*)	set,
		integer, dimension(*)	mi,
		real*8	ttime,
		real*8	time,
		integer	iaxial
	)

!     
!     carbon seal element calculated with Richter method
!      Richter "Rohrhydraulik", Springer ,1971,p. 175
!
!     author: Yannick Muller
!     
      implicit none
!     
      logical identity
      character*8 lakon(*)
      character*81 set(*)
!     
      integer nelem,nactdog(0:3,*),node1,node2,nodem,numf,
     &     ielprop(*),nodef(*),idirf(*),index,iflag,
     &     inv,mi(*),iaxial
!
      real*8 prop(*),v(0:mi(2),*),xflow,f,df(*),r,d,dl,
     &     p1,p2,t1,physcon(*),dvi,pi,s,t2,ttime,time
!     
      if(iflag.eq.0) then
         identity=.true.
!     
         if(nactdog(2,node1).ne.0)then
            identity=.false.
         elseif(nactdog(2,node2).ne.0)then
            identity=.false.
         elseif(nactdog(1,nodem).ne.0)then
            identity=.false.
         endif
!     
      elseif(iflag.eq.1)then
!     
         index=ielprop(nelem)
         d=prop(index+1)
         s=prop(index+2)
         dl=prop(index+3)
         pi=4.d0*datan(1.d0)
!     
         p1=v(2,node1)
         p2=v(2,node2)
         if(p1.ge.p2) then
            inv=1
            t1=v(0,node1)-physcon(1)
         else
            inv=-1
            p1=v(2,node2)
            p2=v(2,node1)
            t1=v(0,node2)-physcon(1)
         endif
!     
         if(lakon(nelem)(2:6).eq.'CARBS') then
!     
!     gapflow
!     Richter "Rohrhydraulik", Springer ,1971,p. 175
!     
            xflow=inv*pi*d*s**3*(p1**2-p2**2)/(24.d0*r*t1*dvi*dl)
            
         elseif(lakon(nelem)(2:6).ne.'CARBS') then
            write(*,*) '*WARNING in Carbon_seal.f'
            write(*,*) 'unable to perform carbon seal calculation'
            write(*,*) 'check input file'
         endif
!     
      elseif(iflag.eq.2)then
!     
         numf=4
         p1=v(2,node1)
         p2=v(2,node2)
         if(p1.ge.p2) then
            inv=1
            xflow=v(1,nodem)*iaxial
            t1=v(0,node1)-physcon(1)
            nodef(1)=node1
            nodef(2)=node1
            nodef(3)=nodem
            nodef(4)=node2
         else
            inv=-1
            p1=v(2,node2)
            p2=v(2,node1)
            xflow=-v(1,nodem)*iaxial
            t1=v(0,node2)-physcon(1)
            nodef(1)=node2
            nodef(2)=node2
            nodef(3)=nodem
            nodef(4)=node1
         endif
!     
         idirf(1)=2
         idirf(2)=0
         idirf(3)=1
         idirf(4)=2
!     
         index=ielprop(nelem)
         d=prop(index+1)
         s=prop(index+2)
         dl=prop(index+3)
         pi=4.d0*datan(1.d0)
         
!     
         if(lakon(nelem)(2:6).eq.'CARBS') then
!     
            f=xflow*t1-pi*d*s**3*(p1**2-p2**2)/(24.d0*r*dvi*dl)
!     
            df(1)=-(pi*d*s**3*p1)/(12.d0*r*dvi*dl)
            df(2)=xflow
            df(3)=t1
            df(4)=(pi*d*s**3*p2)/(12.d0*r*dvi*dl)
!       
         endif

      elseif(iflag.eq.3) then
         p1=v(2,node1)
         p2=v(2,node2)
         if(p1.ge.p2) then
            inv=1
            xflow=v(1,nodem)*iaxial
            t1=v(0,node1)-physcon(1)
            t2=v(0,node2)-physcon(1)
            nodef(1)=node1
            nodef(2)=node1
            nodef(3)=nodem
            nodef(4)=node2
         else
            inv=-1
            p1=v(2,node2)
            p2=v(2,node1)
            xflow=-v(1,nodem)*iaxial
            t1=v(0,node2)-physcon(1)
            t2=v(0,node1)-physcon(1)
            nodef(1)=node2
            nodef(2)=node2
            nodef(3)=nodem
            nodef(4)=node1
         endif

         write(1,*) ''
         write(1,55) ' from node',node1,
     &' to node', node2,':   air massflow rate=',xflow
 55      FORMAT(1x,a,i6,a,i6,a,e11.4,a,a,e11.4,a)

         if(inv.eq.1) then
            write(1,56)'       Inlet node ',node1,':   Tt1=',t1,
     &           ' , Ts1=',t1,' , Pt1=',p1
         
            write(1,*)'             Element',nelem,lakon(nelem)

            write(1,56)'      Outlet node ',node2,':   Tt2=',t2,
     &           ' , Ts2=',t2,' , Pt2=',p2
!     
         else if(inv.eq.-1) then
            write(1,56)'       Inlet node ',node2,':    Tt1=',t1,
     &           ' , Ts1=',t1,' , Pt1=',p1
     &          
            write(1,*)'             Element',nelem,lakon(nelem)

            write(1,56)'      Outlet node ',node1,':    Tt2=',t2,
     &           ' , Ts2=',t2,' , Pt2=',p2

         endif
      
 56      FORMAT(1x,a,i6,a,e11.4,a,e11.4,a,e11.4,a)
      endif
!     
      xflow=xflow/iaxial
      df(3)=df(3)*iaxial
!
      return