calcspringforc.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	calcspringforc (imat, elcon, nelcon, ncmat_, ntmat_, t1l, kode, plicon, nplicon, npmat_, senergy, nener, fk, val)

Function/Subroutine Documentation

calcspringforc()

subroutine calcspringforc	(	integer, intent(in)	imat,
		real*8, dimension(0:ncmat_,ntmat_,*), intent(in)	elcon,
		integer, dimension(2,*), intent(in)	nelcon,
		integer, intent(in)	ncmat_,
		integer, intent(in)	ntmat_,
		real*8, intent(in)	t1l,
		integer, intent(in)	kode,
		real*8, dimension(0:2*npmat_,ntmat_,*), intent(in)	plicon,
		integer, dimension(0:ntmat_,*), intent(in)	nplicon,
		integer, intent(in)	npmat_,
		real*8, intent(inout)	senergy,
		integer, intent(in)	nener,
		real*8, intent(inout)	fk,
		real*8, intent(in)	val
	)

!
!     calculates the spring forc and the spring energy (node-to-face penalty)
!
      implicit none
!
      integer i,imat,ncmat_,ntmat_,kode,niso,id,nplicon(0:ntmat_,*),
     &    npmat_,nelcon(2,*),nener
!
      real*8 t1l,elcon(0:ncmat_,ntmat_,*),elconloc(21),plconloc(802),
     &  xk,fk,val,xiso(200),yiso(200),plicon(0:2*npmat_,ntmat_,*),
     &  senergy
!
      intent(in) imat,elcon,nelcon,ncmat_,ntmat_,t1l,val,
     &  kode,plicon,nplicon,npmat_,nener
!
      intent(inout) senergy,fk
!     
!     interpolating the material data
!     
      call materialdata_sp(elcon,nelcon,imat,ntmat_,i,t1l,
     &     elconloc,kode,plicon,nplicon,npmat_,plconloc,ncmat_)
!     
!     calculating the spring force and the spring constant
!     
      if(kode.eq.2)then
         xk=elconloc(1)
         fk=xk*val
         if(nener.eq.1) then
            senergy=fk*val/2.d0
         endif
      else
         niso=int(plconloc(801))
         do i=1,niso
            xiso(i)=plconloc(2*i-1)
            yiso(i)=plconloc(2*i)
         enddo
         call ident(xiso,val,niso,id)
         if(id.eq.0) then
            xk=0.d0
            fk=yiso(1)
            if(nener.eq.1) then
               senergy=fk*val
            endif
         elseif(id.eq.niso) then
            xk=0.d0
            fk=yiso(niso)
            if(nener.eq.1) then
               senergy=yiso(1)*xiso(1)
               do i=2,niso
                  senergy=senergy+(xiso(i)-xiso(i-1))*
     &                 (yiso(i)+yiso(i-1))/2.d0
               enddo
               senergy=senergy+(val-xiso(niso))*yiso(niso)
            endif
         else
            xk=(yiso(id+1)-yiso(id))/(xiso(id+1)-xiso(id))
            fk=yiso(id)+xk*(val-xiso(id))
            if(nener.eq.1) then
               senergy=yiso(1)*xiso(1)
               do i=2, id
                  senergy=senergy+(xiso(i)-xiso(i-1))*
     &                 (yiso(i)+yiso(i-1))/2.d0
               enddo
               senergy=senergy+(val-xiso(id))*(fk+yiso(id))/2.d0
            endif
         endif
      endif
!     
      return