applympc.f File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	applympc (nface, ielfa, is, ie, ifabou, ipompc, vfa, coefmpc, nodempc, ipnei, neifa, labmpc, xbounact, nactdoh, ifaext, nfaext)

Function/Subroutine Documentation

applympc()

subroutine applympc	(	integer, intent(in)	nface,
		integer, dimension(4,*), intent(in)	ielfa,
		integer, intent(in)	is,
		integer, intent(in)	ie,
		integer, dimension(*), intent(in)	ifabou,
		integer, dimension(*), intent(in)	ipompc,
		real*8, dimension(0:7,*), intent(inout)	vfa,
		real*8, dimension(*), intent(in)	coefmpc,
		integer, dimension(3,*), intent(in)	nodempc,
		integer, dimension(*), intent(in)	ipnei,
		integer, dimension(*), intent(in)	neifa,
		character*20, dimension(*), intent(in)	labmpc,
		real*8, dimension(*), intent(in)	xbounact,
		integer, dimension(*), intent(in)	nactdoh,
		integer, dimension(*), intent(in)	ifaext,
		integer, intent(in)	nfaext
	)

!
!     applies MPC's to the faces
!
      implicit none
!
      character*20 labmpc(*)
!
      integer i,j,nface,ielfa(4,*),ipointer,is,ie,ifabou(*),mpc,
     &  ipompc(*),index,iel,iface,nodempc(3,*),ipnei(*),neifa(*),
     &  nactdoh(*),ielorig,ifaext(*),nfaext,k
!
      real*8 coefmpc(*),denominator,vfa(0:7,*),sum,xbounact(*),
     &  coefnorm
!
      intent(in) nface,ielfa,is,ie,ifabou,ipompc,coefmpc,
     &  nodempc,ipnei,neifa,labmpc,xbounact,nactdoh,ifaext,nfaext
!
      intent(inout) vfa
!
c$omp parallel default(none)
c$omp& shared(nfaext,ifaext,ielfa,ifabou,ipompc,nodempc,coefmpc,
c$omp&        xbounact,nactdoh,neifa,ipnei,vfa,is,ie)
c$omp& private(k,i,ipointer,mpc,index,sum,coefnorm,ielorig,iel,iface)
c$omp do
      do k=1,nfaext
         i=ifaext(k)
         if(ielfa(2,i).ge.0) cycle
         ipointer=-ielfa(2,i)
         do j=is,ie
            if(ifabou(ipointer+j).ge.0) cycle
            mpc=-ifabou(ipointer+j)
!
            index=ipompc(mpc)
            sum=0.d0
            coefnorm=0.d0
            do
               if(index.eq.0) exit
               if(nodempc(1,index).lt.0) then
!
!                 a negative number refers to a boundary
!                 condition (fields nodeboun, ndirboun..)
!                 resulting from a SPC in local coordinates
!                  
                  sum=sum+coefmpc(index)*xbounact(-nodempc(1,index))
               else
!
!                 face term
!
                  ielorig=int(nodempc(1,index)/10.d0)
                  iel=nactdoh(ielorig)
                  iface=nodempc(1,index)-10*ielorig
                  sum=sum+coefmpc(index)
     &                 *vfa(nodempc(2,index),neifa(ipnei(iel)+iface))
                  coefnorm=coefnorm+coefmpc(index)**2
               endif
               index=nodempc(3,index)
            enddo
!
!           distribute the sum across all terms which are not
!           fixed by boundary conditions
!
            index=ipompc(mpc)
            do
               if(index.eq.0) exit
               if(nodempc(1,index).gt.0) then
                  ielorig=int(nodempc(1,index)/10.d0)
                  iel=nactdoh(ielorig)
                  iface=nodempc(1,index)-10*ielorig
                  vfa(nodempc(2,index),neifa(ipnei(iel)+iface))=
     &               vfa(nodempc(2,index),neifa(ipnei(iel)+iface))-
     &               sum*coefmpc(index)/coefnorm
               endif
               index=nodempc(3,index)
            enddo
         enddo
      enddo
c$omp end do
c$omp end parallel
!     
      return